Thingspeak ile Veri Grafiği Çıkarma

Merhaba Arkadaşlar, Bugünkü yazımızda Thingspeak , veri grafiklerini çıkarma ve dünyanın herhangi bir yerinden verileri analiz etmeye olanak sağlayan mükemmel bir IoT yardımcınızdır.

Projemiz esp tabanlı geliştirme kartlarında çalışmaktadır ama benim kullandığım WeMos D1 mini geliştirme kartı. Bu karttan bahsetmeyeceğim ama daha önce burada da bahsettiğim kendi el emeğim göz nurum modüllerimi kullandım.

Projemizin çalışması şu şekilde. Öncelikle thingspeak.com adresinde kullanıcı adınızı ve şifrenizi tanımlayın daha sonrasında ise kanal oluşturmanız gerekmektedir.

Kanal oluşturduktan sonra oluşturduğunuz kanalın içerisine iki adet field açın bunlara isim verebilirsiniz. Yukardaki resimde oluşturduktan 20 dk sonra aldığım iki değerin grafiğini görüyorsunuz.

Projemizde DHT22 ile sıcaklık ve nem değerleri her 10 dk. da bir thingspeak sitesinde oluşturduğumuz kanala kayıt edilmektedir. Programlama ile bu değer kısaltabilir.

Eğer elinizde herhangi bir DHT11 yada DHT22 sensörü varsa bağlantılarını yaparak çok rahat kullanabilirsiniz.

Buradan indirebilirsiniz
Programımız

/**The MIT License (MIT)
Copyright (c) 2015 by Daniel Eichhorn
Permission is hereby granted, free of charge, to any person obtaining a copy
of this software and associated documentation files (the "Software"), to deal
in the Software without restriction, including without limitation the rights
to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
copies of the Software, and to permit persons to whom the Software is
furnished to do so, subject to the following conditions:
The above copyright notice and this permission notice shall be included in all
copies or substantial portions of the Software.
THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
SOFTWARE.
*/

#include <ESP8266WiFi.h>
#include "DHT.h"


/***************************
 * Begin Settings
 **************************/


const char* ssid     = "ssid";
const char* password = "sifre";

const char* host = "api.thingspeak.com";
//olusturdugunuz kanalin API yazma kodunu kopyala
const char* THINGSPEAK_API_KEY = "UL4NAWBFZW49ZMHFR";

// DHT Settings
#define DHTPIN D1     // DHT pinini tanimla

// DHT tipini sec
//#define DHTTYPE DHT11   // DHT 11
#define DHTTYPE DHT22   // DHT 22  (AM2302), AM2321
//#define DHTTYPE DHT21   // DHT 21 (AM2301)

const boolean IS_METRIC = true;

// Update every 600 seconds = 10 minutes. Min with Thingspeak is ~20 seconds
const int UPDATE_INTERVAL_SECONDS = 600;

/***************************
 * End Settings
 **************************/
 
// Initialize the temperature/ humidity sensor
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(115200);
  delay(10);

  // We start by connecting to a WiFi network

  Serial.println();
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  
  WiFi.begin(ssid, password);
  
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }

  Serial.println("");
  Serial.println("WiFi connected");  
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
}

void loop() {      
    Serial.print("connecting to ");
    Serial.println(host);
    
    // Use WiFiClient class to create TCP connections
    WiFiClient client;
    const int httpPort = 80;
    if (!client.connect(host, httpPort)) {
      Serial.println("connection failed");
      return;
    }

    // read values from the sensor
    float humidity = dht.readHumidity();
    float temperature = dht.readTemperature(!IS_METRIC);
    
    // We now create a URI for the request
    String url = "/update?api_key=";
    url += THINGSPEAK_API_KEY;
    url += "&field1=";
    url += String(temperature);
    url += "&field2=";
    url += String(humidity);
    
    Serial.print("Requesting URL: ");
    Serial.println(url);
    
    // This will send the request to the server
    client.print(String("GET ") + url + " HTTP/1.1\r\n" +
                 "Host: " + host + "\r\n" + 
                 "Connection: close\r\n\r\n");
    delay(10);
    while(!client.available()){
      delay(100);
      Serial.print(".");
    }
    // Read all the lines of the reply from server and print them to Serial
    while(client.available()){
      String line = client.readStringUntil('\r');
      Serial.print(line);
    }
    
    Serial.println();
    Serial.println("closing connection");


  // Go back to sleep. If your sensor is battery powered you might
  // want to use deep sleep here
  delay(1000 * UPDATE_INTERVAL_SECONDS);
}


Bir Cevap Yazın

Time limit is exhausted. Please reload CAPTCHA.